‘壹’ 51单片机红外遥控发射接收的问题待高手解答。。。不胜感激！
用STC12C5A60S2，用其PCA软件定时器就不存在这个问题了，可以做的很精确，值得说明的是13US是对的；另外用T0和T1也是可以的，用其1T模式，几条语句占用不了多少时间，在送的数中处理一下就OK了。
‘贰’ 51单片机遥控器（红外），用什么来接收呢
最好还是买一个红接收头，接收灵敏度高，接收距离远，自己不用加任何电路。加上5V电源就能用了，输出的就是数字信号了，非常适合单片机编程。如HS0038B。
‘叁’ 单片机接收红外遥控器信号，并通过232串口送到PC机上，显示所读取的按键的用户码和数据码
这个不就是一个红外遥控和串口通讯么？一般的开发板都可以实现的啦。不过电脑上需要用那个串口通讯助手。我这里有一些资料，需要可以来找我，随时都在线，等待回复。如果不在线，可以给我留言，看到到马上回复。
‘肆’ 红外接收原理是把一串信号全部接收处理后发送到单片机还是一个一个数据接收
你要知道 红外遥控码是什么样，一般先低电平，再过数ms的高电平，紧接着就是真正的 0 1
0 1之类的数据，单片机就是解析后面的一大串0 和 1 ，0和1的高低电平持续时间不同，一般有32位 。解析一位 存一位，够32 位后，再取出8位 8位地判断键值。当然也可以一次存一大串高低电平的持续时间值，然后再判断是0和1，但这样要求的内存很大，低档单片机常出现内存不足情况。
‘伍’ 求单片机C51红外线收发方案(最好有详细解释)
红外线遥控器解码程序
2007-02-07 18:52 红外线遥控是目前使用最广泛的一种通信和遥控手段。由于红外线遥控装置具有体积小、功耗低、功能强、成本低等特点，因而，继彩电、录像机之后，在录音机、音响设备、空凋机以及玩具等其它小型电器装置上也纷纷采用红外线遥控。现在工业设备中，也已经广泛在使用。。。。。
1 红外遥控系统
通用红外遥控系统由发射和接收两大部分组成，应用编/解码专用集成电路芯片来进行控制操作，如图1所示。发射部分包括键盘矩阵、编码调制、LED红外发送器；接收部分包括光、电转换放大器、解调、解码电路。
2 遥控发射器及其编码
遥控发射器专用芯片很多，根据编码格式可以分成脉冲宽度调制和脉冲相位调制两大类，这里我们以运用比较广泛，解码比较容易的脉冲宽度调制来加以说明，现以3310组成发射电路为例说明编码原理。当发射器按键按下后，即有遥控码发出，所按的键不同遥控编码也不同。这种遥控码具有以下特征：
采用脉宽调制的串行码，以脉宽为0.565ms、间隔0.56ms、周期为1.125ms的组合表示二进制的“0”；以脉宽为0.565ms、间隔1.685ms、周期为2.25ms的组合表示二进制的“1”
上述“0”和“1”组成的42位二进制码经38kHz的载频进行二次调制以提高发射效率，达到降低电源功耗的目的。然后再通过红外发射二极管产生红外线向空间发射，
3310产生的遥控编码是连续的42位二进制码组，其中前26位为用户识别码，能区别不同的红外遥控设备，防止不同机种遥控码互相干扰。后16位为8位的操作码和8位的操作反码用于核对数据是否接收准确。
当遥控器上任意一个按键按下超过36ms时，LC7461芯片的振荡器使芯片激活，将发射一个特定的同步码头，对于接收端而言就是一个9ms的低电平,和一个4.5ms的高电平，这个同步码头可以使程序知道从这个同步码头以后可以开始接收数据。
解码的关键是如何识别“0”和“1”，从位的定义我们可以发现“0”、“1”均以0.56ms的低电平开始，不同的是高电平的宽度不同，“0”为0.56ms,“1”为1.68ms,所以必须根据高电平的宽度区别“0”和“1”。如果从0.56ms低电平过后，开始延时，0.56ms以后，若读到的电平为低，说明该位为“0”，反之则为“1”，为了可靠起见，延时必须比0.56ms长些，但又不能超过1.12ms,否则如果该位为“0”，读到的已是下一位的高电平，因此取（1.12ms+0.56ms）/2=0.84ms最为可靠，一般取0.84ms左右即可。
根据红外编码的格式，程序应该等待9ms的起始码和4.5ms的结果码完成后才能读码。
接收器及解码
LT0038是塑封一体化红外线接收器，它是一种集红外线接收、放大、整形于一体的集成电路，不需要任何外接元件，就能完成从红外线接收到输出与TTL电平信号兼容的所有工作，没有红外遥控信号时为高电平，收到红外信号时为低电平，而体积和普通的塑封三极管大小一样，它适合于各种红外线遥控和红外线数据传输。
下面是一个对51ISP编程实验开发板配套的红外线遥控器的解码程序，它可以把红外遥控器每一个按键的键值读出来，并且通过实验板上P1口的8个LED显示出来，在解码成功的同时并且能发出“嘀嘀嘀”的提示音。
ORG 0000H
AJMP MAIN;转入主程序
ORG 0003H ;外部中断P3.2脚INT0入口地址
AJMP INT ;转入外部中断服务子程序（解码程序）
;以下为主程序进行CPU中断方式设置
MAIN:SETB EA ;打开CPU总中断请求
SETB IT0 ;设定INT0的触发方式为脉冲负边沿触发
SETB EX0 ;打开INT0中断请求
;以下对单片机的所有引脚进行初始化，全部设置成高电平
MOV P2,#11111111B
AJMP $
;以下为进入P3.2脚外部中断子程序，也就是解码程序
INT: CLR EA ;暂时关闭CPU的所有中断请求
MOV R6,#10
SB: ACALL YS1;调用882微秒延时子程序
JB P3.2,EXIT;延时882微秒后判断P3.2脚是否出现高电平如果有就退出解码程序
DJNZ R6, SB;重复10次，目的是检测在8820微秒内如果出现高电平就退出解码程序
;以上完成对遥控信号的9000微秒的初始低电平信号的识别。
JNB P3.2, $ ;等待高电平避开9毫秒低电平引导脉冲
ACALL YS2 ;延时4.74毫秒避开4.5毫秒的结果码
MOV R7,#26;忽略前26位系统识别码
JJJJA:JNB P3.2,$;等待地址码第一位的高电平信号
LCALL YS1;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
MOV C,P3.2;将P3.2引脚此时的电平状态0或1存入C中
JNC UUUA;如果为0就跳转到UUUA
LCALL YS3;检测到高电平1的话延时1毫秒等待脉冲高电平结束
UUUA: DJNZ R7,JJJJA
MOV R1,#1AH ;设定1AH为起始RAM区
MOV R2,#2;接收从1AH到1BH的2个内存,用于存放操作码和操作反码
PP: MOV R3,#8;每组数据为8位
JJJJ: JNB P3.2,$;等待地址码第一位的高电平信号
LCALL YS1;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
MOV C,P3.2;将P3.2引脚此时的电平状态0或1存入C中
JNC UUU;如果为0就跳转到UUU
LCALL YS3;检测到高电平1的话延时1毫秒等待脉冲高电平结束
UUU: MOV A,@R1;将R1中地址的给A
RRC A;将C中的值0或1移入A中的最低位
MOV @R1,A;将A中的数暂时存放在R1数值的内存中
DJNZ R3,JJJJ;接收满8位换一个内存
INC R1;对R1中的值加1，换下一个RAM
DJNZ R2,PP ;接收完8位数据码和8位数据反码，存放在1AH/1BH中
MOV A,1AH
CPL A;对1AH取反后和1BH比较
CJNE A,1BH,EXIT;如果不等表示接收数据发生错误,放弃
MOV P1,1AH;将按键的键值通过P1口的8个LED显示出来!
CLR P2.0;蜂鸣器鸣响－嘀嘀嘀－的声音，表示解码成功
LCALL YS2
LCALL YS2
LCALL YS2
SETB P2.0;蜂鸣器停止（使用时可以将J2的YINYUE脚用跳线接J4 的XS1脚才可以使用蜂鸣器）可以看原理图
EXIT: SETB EA ;允许中断
RETI ;退出解码子程序
YS1: MOV R4,#20 ;延时子程序1，精确延时882微秒
D1: MOV R5,#20
DJNZ R5,$
DJNZ R4,D1
RET
YS2: MOV R4,#10 ;延时子程序2，精确延时4740微秒
D2: MOV R5,#235
DJNZ R5,$
DJNZ R4,D2
RET
YS3: MOV R4,#2;延时程序3，精确延时1000微秒
D3:MOV R5,#248
DJNZ R5,$
DJNZ R4,D3
RET
END
以上程序紧供参考。
0A 01
11 12 13 14
15 16 17 18
19 10 1A 1B
0E 02 03 1C
06 04 05 0C
0D 08 09 1D
00 1F 1E 0B
07 0F
这是按照红外遥控器按键的实际位置给出的32个按键的键值（16进制）
‘陆’ 单片机红外接收的中断程序怎样理解
你的思路是正确的。
不过你贴的程序看不到引导码的处理过程，或者说没法知道startflag怎么置1的。最好也贴出来。
如果你这个接收程序的中断处理部分完整的话，可以确定所用的单片机不具有修改触发边沿的功能。只能根据第一个下降沿（引导码）和第一个用户码之间的时间来处理（减去0电平的时间）。
从程序上看，
if(startflag)
只是判断可能是起始标记。
if(irtime>32&&irtime<63)
//引导码
8-16ms间
bitnum=0;
这个判断是否为引导码。如果是，则将数组键置0，准备开始存储数据。即：
irdata[bitnum]=irtime;
irtime=0;//这个就不说了
bitnum++;//这个本来也不该说的，不过结合前面的引导码判断，就有问题了：
1、如果遥控器发射过程中红外线被挡住，irtime会很长···还需要继续存储么？
2、如果接收被干扰，会插入高电平，irtime
不确定···
3·······
简单说，判断过于简单，没法实用的。
话说，你自己有能力写个好的，为嘛还参考别人的？
‘柒’ 51单片机红外接收端的程序怎么写,我想知道写的方法和原理,最好有一个具体的模版,好让我参考.
这是采用STC12C5A60S2单片机的红外解码程序及其说明。
;采用脉宽调制的串行码，以脉宽为0.565ms、间隔0.56ms、周期为1.125ms的组合表示二进制的"0"；
;以脉宽为0.565ms、间隔1.685ms、周期为2.25ms的组合表示二进制的"1
;上述"0"和"1"组成的32位二进制码经38kHz的载频进行二次调制以提高发射效率，
;达到降低电源功耗的目的。然后再通过红外发射二极管产生红外线向空间发射
;遥控编码是连续的32位二进制码组，其中前16位为用户识别码，能区别不同的电器设备，
;防止不同机种遥控码互相干扰。该芯片的用户识别码固定为十六进制01H
;后16位为8位操作码（功能码）及其反码。
;当一个键按下超过36ms，振荡器使芯片激活，将发射一组108ms的编码脉冲,这108ms发射代码由一个起始码（9ms）,
;一个结果码（4.5ms）,低8位地址码（9ms~18ms）,高8位地址码（9ms~18ms）,8位数据码（9ms~18ms）
;和这8位数据的反码（9ms~18ms）组成。如果键按下超过108ms仍未松开，
;接下来发射的代码（连发代码）将仅由起始码（9ms）和结束码（2.5ms）组成。
;
;解码的关键是如何识别"0"和"1"，接收端而言，"0"是0.56ms的高+0.56ms的低。"1"是1.68ms的高+0.56ms的低。
;所以可以根据高电平的宽度区别"0"和"1"。当高电平出现时开始延时，0.56ms以后，若读到的电平为低，
;说明该位为"0"，反之则为"1"，为了可靠起见，延时必须比0.56ms长些，但又不能超过1.12ms,否则如果该位为"0"，
;读到的已是下一位的高电平，因此取（1.12ms+0.56ms）/2=0.84ms最为可靠，一般取0.84ms左右均可。
;为了共用引导部分延时程序，这里用0.9ms延时。
;-------------红外解码程序---------------------------
EXINT0:
PUSH ACC
PUSH PSW
PUSH 1
PUSH 2
PUSH 6
CLR EA ;暂时关闭中断请求
MOV R6,#10
EXINT10:
LCALL DELAY09MS ;调用900us延时子程序
JB IRIN,INTOUT1 ;判断P3.2是否有高电平，如果有就退出解码程序
DJNZ R6,EXINT10 ;循环10次，检测在900微妙中是否存在高电平。以上完成对遥控信号的9000微秒的初始低电平信号的识别。
JNB IRIN,$ ;等待高电平避开9毫秒低电平引导脉冲
LCALL DELAY45MS ;延时4.5毫秒
;-------------接受32位代码--------------------------
MOV R1,#IRUSERL
MOV R2,#04H
EXINT101:
MOV R6,#08H ;每组数据位8位
EXINT102:
JNB IRIN,$ ;等待地址码第一组数据的高电平信号
LCALL DELAY09MS ;高电平开始后延时判断信号此时的高/低状态
MOV C,IRIN ;将P3.2引脚此时的电平状态0或1存入C中
JNC INT1OUT ;如果为0跳出
LCALL DELAY1MS
INT1OUT:
MOV A,@R1
RRC A ;将C中的数据0/1移入A中最低位
MOV @R1,A ;将A中的数据暂存在R1
DJNZ R6,EXINT102 ;接受完8位代码
INC R1
DJNZ R2,EXINT101 ;接受完4组32位代码
;--------------数据码比较-------------------------------
MOV A,IRDATAL
; LCALL SENDRXDAT
MOV A,IRDATAL
CPL A
CJNE A,IRDATAH,INTOUT1 ;判断数码正误，不等退出
MOV IR_DAT,IRDATAL ;相等则保存正确数据
MOV A,IR_DAT
; LCALL SENDRXDAT
SETB IRBIT
INTOUT1:
LCALL DELAY45MS
SETB EA ;允许中断
POP 6
POP 2
POP 1
POP PSW
POP ACC
RETI
;;*****************11.0592*900=9953******************
DELAY09MS: ;6
PUSH 4 ;4
PUSH 3 ;4
MOV R4,#20 ;2
DLY900:
MOV R3,#122 ;2
DJNZ R3,$ ;4
DJNZ R4,DLY900 ;4
MOV R4,#11 ;2
DJNZ R4,$ ;4
POP 3 ;3
POP 4 ;3
RET ;4
;TOTAL=9952
;;*****************11.0592*560=6193******************
DELAY056: ;6
PUSH 4 ;4
PUSH 3 ;4
MOV R4,#12 ;2
DLY5600:
MOV R3,#122 ;2
DJNZ R3,$ ;4
DJNZ R4,DLY5600 ;4
MOV R4,#71 ;2
DJNZ R4,$ ;4
POP 3 ;3
POP 4 ;3
RET ;4
;TOTAL=6194
;;*****************11.0592*4500=49766****************
DELAY45MS: ;6
PUSH 4 ;4
PUSH 3 ;4
MOV R4,#52 ;2
DLY45:
MOV R3,#236 ;2
DJNZ R3,$ ;4
DJNZ R4,DLY45 ;4
MOV R4,#85 ;2
DJNZ R4,$ ;4
POP 3 ;3
POP 4 ;3
RET ;4
;;TOTAL=49768
;;*****************11.0592*1000=11059****************
DELAY1MS: ;6
PUSH 4 ;4
PUSH 3 ;4
MOV R4,#20 ;2
DLY1MS:
MOV R3,#136 ;2
DJNZ R3,$ ;4
DJNZ R4,DLY1MS ;4
MOV R4,#8 ;2
DJNZ R4,$ ;4
POP 3 ;3
POP 4 ;3
RET ;4
;TOTAL=11060
;;***************************************************
DELAY100US: ;6
PUSH 4 ;4
MOV R4,#140 ;2
DJNZ R4,$ ;4
MOV R4,#131 ;2
DJNZ R4,$ ;4
POP 4 ;3
RET ;4
;TOTAL=1105
;;***************************************************
‘捌’ 51单片机最小系统怎样连接红外遥控模块
红外信号的发射由红外发射电路中的红外发光二极管完成，通常情况下为了提高抗干扰能力与降低电源消耗，遥控器将遥控信号（二进制脉冲码）调制在载波（载波是传送信息的物理基础和承载工具）上经放大后发送至红外二极管，再由二极管转换为红外信号发送出去。遥控器上不同的按键有着不一样的键值，按下相对应的键，红外二极管就会发送对应的信号，接收装置接收到信号后会对信号进行信号解调后会得到相应按键的键值，再根据不同的键值执行相应的操作。
‘玖’ 基于单片机的红外遥控收发系统的设计与实现
红外遥控一般采用38KHz载波
‘拾’ 51单片机红外遥控红外接收引脚是否应该串接电阻
不串接电阻，可以接上拉电阻。