⑴ 单片机播放音乐里的音乐代码是怎么得到的有什么软件能将歌曲直接转换成16进制代码
把简谱中每个唱名对应的频率找出来，比如C调的1对应264Hz左右。
然后把这些频率通过公式转换成初值再换算成十六进制。
比如你用的是定时的工作方式1，则可以这位算:（假设晶振是12MHz）
X=2^16-10^6/(264*2)=63642因为要计算的是半周期对应的初值，所以频率就是2倍。
十六进制就是：F89A
好像没有什么软件吧，有的话告诉我一声哦。
⑵ 在单片机中怎么确定音乐节拍
这种LED随音乐闪烁，效果上类似于音响设备的电平指示器。电路很多，可用分立元件，也可用现成的IC,如日本东芝公司早期的TA7666B等，如图所示：此图可接21只LED，排成往两边闪的效果，中间一只LED长亮，作为电源指示。输入端接音频信号，信号弱，LED闪的少，信号强，LED闪的多，直至闪到头。
⑶ 这些单片机代码根据曲谱怎么写出来的，求大神详细教啊！
哈哈，LZ有求知欲很好嘛！其实原理是这样的：
首先，音乐有哪几个最基本的要素？
1，音高（频率） 2，节拍（音符长度）3，强度。
其次，单片机演奏音乐的原理？
1，硬件方面：以I/o口输出方波，驱动无源蜂鸣器震动，方波频率与乐谱中音符的频率对应（实现了音乐的第1要素）
2，软件方面，有两点
（1）如何产生某一频率的方波？通过定时器产生周期性中断，在中断里将IO口的电平翻转即可，中断周期（即定时器应赋的初值）可以由需要的频率计算得到。
（2）如何控制音符的长度（即音乐的第2要素）？从程序结构上来讲，有几种实现途径，我能想到的：再使用一个定时器，它的中断周期固定，以它作为长度的基准。比如，定为10ms中断一次，中断100次就是1秒，那么演奏节拍为2/4拍一分钟60拍的二分音符小字一组A(440Hz),就是200次中断。定时器0控制I/O口输出频率440Hz的方波，并等定时器1中断 200次之后，就切换到下一音符。这样就实现了乐音输出。
3.当然，这样的音乐是控制不了强弱的，无法实现音乐的要素3。非常简陋，只能将就。
程序最下面的数组就是单片机的“乐谱”，每一对元素，前面是音高（对应的宏给其对应的在音阶里的位置进行了编号，后面是音符长度）。m_note数组存储的就是演奏某一频率的乐音对应的定时器中断周期。
⑷ 单片机对于音乐的编程中 ，音符的十六位数据表是怎样
只有音乐发声汇编程序，没有加入LED灯，供参考。数据代码已改为小星星发声
;**********************************************
ORG 0000H
SJMP MAIN
ORG 0BH
AJMP TIME0
;*************主程序************************
MAIN: MOV SP,#60
MOV TMOD,#01H ;T0定时工作方式
MOV IE,#82H ;CPU 中断允许，T0中断允许
START0: MOV 30H,#00H ;TABLE 相对地址指针
NEXT: MOV A,30H
MOV DPTR,#TABLE ;到TABLE处取 简谱码 节拍 码
MOVC A,@A+DPTR
MOV R2,A ;取到的简谱码 节拍码 暂存于R2中
JZ ENDF ;取到 00 结束
ANL A,#0FH ;否，取低四位 节拍 码
MOV R5,A ;将节拍码存于R5中
MOV A,R2 ;简谱码 节拍 码 给A
SWAP A ;高4位 与 低4位 交换
ANL A,#0FH ;取简谱 码
JNZ SING ;取到的简谱 码不是0,则去发声
CLR TR0 ;取到0 则不发声
SJMP DLY1 ;节拍延时子程序( 随节拍码变化,延时时间不同)
;---------------发声-----------------------
SING: DEC A ;取到的简谱码减1
;（简谱码计数值16位数据存储首地址从TABLE1 《相对地址》0处开始放起，所以要减1）
MOV 22H,A ;存入(22H)中
RL A ;乘2 因为取的数据占两字节（16位）
;所以指针增加量要乘2
MOV DPTR,#TABLE1
;...........简谱码转换为相应定时器16位计数值.............
MOVC A,@A+DPTR ;到TABLE1取相应的高字节计数值
MOV TH0,A ;高字节计数值存入TH0和(21H)中
MOV 21H,A
MOV A,22H ;减1的简谱码给A
RL A ;乘2 因为取的数据占两字节（16位）
;所以指针增加量要乘2
INC A ;A 增加 取下一个字节计数值
;...........简谱码转换为相应定时器16位计数值.............
MOVC A,@A+DPTR ;到TABLE1取相应的低字节计数值
MOV TL0,A ;低字节计数值存入TL0和(20H)中
MOV 20H,A
SETB TR0 ;启动T0定时器让喇叭发出不同频率声音
;---------------节拍延时-------------------
DLY1: ACALL DELAY ;基本单位时间为1/4拍 187ms
INC 30H ;取下一个简谱码 节拍 码
SJMP NEXT
;---------------歌放完结束---------------
ENDF: CLR TR0 ;关闭T0定时器
AJMP START0 ;反复循环
;****T0中断子程序(用来驱动喇叭发出不同频率声音)**************
TIME0: PUSH ACC
PUSH PSW
MOV TL0,20H ;重装计数值
MOV TH0,21H
CPL P3.7 ;驱动发声
POP PSW
POP ACC
RETI
;******************节拍延时187ms****************************
DELAY: MOV R7,#187 ;187ms延时子程序
DLY2: MOV R4,#02
DLY3: MOV R3,#248
DJNZ R3,$
DJNZ R4,DLY3
DJNZ R7,DLY2
DJNZ R5,DELAY
RET
;*******音符T值表(用来让定时器发出不同的频率)**DW 表示一个 计数值 占两个字节存储单元***************
TABLE1: DW 64260,64400,64524,64580,64684 ;低音SO 低音LA 低音SI /中音DO 中音RE
DW 64777,64820,64898,64968,65030 ;中音MI 中音FA 中音SO 中音LA 中音SI
DW 65058,65110,65157,65178,65217 ;高音DO 高音RE 高音MI 高音FA 高音SO
;*********简谱码 节拍码(高4位简谱码 ,低4位节拍码)*************
TABLE: DB 44H,44H,84H,84H ; 1 1 5 5
DB 094H,094H,88h ; 6 6 5 -
DB 74H,74H,63H,63H ; 4 4 3 3
DB 52H,52H,48h ; 2 2 1-
DB 84H,84H,74H,74H ; 5 5 4 4
DB 64H,64H,58h ; 3 3 2-
DB 84H,84H,74H,74H ; 5 5 4 4
DB 64H,64H,58h ; 3 3 2-
DB 44H,44H,84H,84H ; 1 1 5 5
DB 094H,094H,88h ; 6 6 5 -
DB 74H,74H,63H,63H ; 4 4 3 3
DB 52H,52H,48h ; 2 2 1-
END
加入了LED灯，水平有限，效果有点不太好
;**********************************************
ORG 0000H
SJMP MAIN
ORG 0BH
AJMP TIME0
;*************主程序************************
MAIN: MOV SP,#60
MOV TMOD,#01H ;TO定时工作方式
MOV IE,#82H ;CPU 中断允许，TO中断允许
START0: MOV 30H,#00H ;TABLE 相对地址指针
NEXT: MOV A,30H
MOV DPTR,#TABLE ;到TABLE处取 简谱码 节拍 码
MOVC A,@A+DPTR
MOV R2,A ;取到的简谱码 节拍码 暂存于R2中
JZ ENDF ;取到 00 结束
ANL A,#0FH ;否，取低四位 节拍 码
MOV R5,A ;将节拍码存于R5中
MOV A,R2 ;简谱码 节拍 码 给A
SWAP A ;高4位 与 低4位 交换
ANL A,#0FH ;取简谱 码
JNZ SING ;取到的简谱 码不是0,则去发声
CLR TR0 ;取到0 则不发声
SJMP DLY1 ;节拍延时子程序( 随节拍码变化,延时时间不同)
;---------------发声-----------------------
SING: DEC A ;取到的简谱码减1
;（简谱码计数值16位数据存储首地址从TABLE1 《相对地址》0处开始放起，所以要减1）
MOV 22H,A ;存入(22H)中
RL A ;乘2 因为取的数据占两字节（16位）
;所以指针增加量要乘2
MOV DPTR,#TABLE1
;...........简谱码转换为相应定时器16位计数值.............
MOVC A,@A+DPTR ;到TABLE1取相应的高字节计数值
MOV TH0,A ;高字节计数值存入TH0和(21H)中
MOV 21H,A
MOV A,22H ;减1的简谱码给A
RL A ;乘2 因为取的数据占两字节（16位）
;所以指针增加量要乘2
INC A ;A 增加 取下一个字节计数值
;...........简谱码转换为相应定时器16位计数值.............
MOVC A,@A+DPTR ;到TABLE1取相应的低字节计数值
MOV TL0,A ;低字节计数值存入TL0和(20H)中
MOV 20H,A
SETB TR0 ;启动T0定时器让喇叭发出不同频率声音
;---------------节拍延时-------------------
DLY1: ACALL DELAY ;基本单位时间为1/4拍 187ms
INC 30H ;取下一个简谱码 节拍 码
CPL P1.0 LED灯 闪烁
CPL P1.1
CPL P1.2
CPL P1.3
CPL P1.4
CPL P1.5
CPL P1.6
CPL P1.7
SJMP NEXT
;---------------歌放完结束---------------
ENDF: CLR TR0 ;关闭T0定时器
AJMP START0 ;反复循环
;****T0中断子程序(用来驱动喇叭发出不同频率声音)**************
TIME0: PUSH ACC
PUSH PSW
MOV TL0,20H ;重装计数值
MOV TH0,21H
CPL P3.7 ;驱动发声
POP PSW
POP ACC
RETI
;******************节拍延时187ms****************************
DELAY: MOV R7,#187 ;187ms延时子程序
DLY2: MOV R4,#02
DLY3: MOV R3,#248
DJNZ R3,$
DJNZ R4,DLY3
DJNZ R7,DLY2
DJNZ R5,DELAY
RET
;*******音符T值表(用来让定时器发出不同的频率)**DW 表示一个 计数值 占两个字节存储单元***************
TABLE1: DW 64260,64400,64524,64580,64684 ;低音SO 低音LA 低音SI /中音DO 中音RE
DW 64777,64820,64898,64968,65030 ;中音MI 中音FA 中音SO 中音LA 中音SI
DW 65058,65110,65157,65178,65217 ;高音DO 高音RE 高音MI 高音FA 高音SO
;*********简谱码 节拍码(高位简谱码 ,低位节拍码)*************
TABLE: DB 44H,44H,84H,84H ; 1 1 5 5
DB 094H,094H,88h ; 6 6 5 - -表示有节拍
DB 74H,74H,63H,63H ; 4 4 3 3
DB 52H,52H,48h ; 2 2 1-
DB 84H,84H,74H,74H ; 5 5 4 4
DB 64H,64H,58h ; 3 3 2-
DB 84H,84H,74H,74H ; 5 5 4 4
DB 64H,64H,58h ; 3 3 2-
DB 44H,44H,84H,84H ; 1 1 5 5
DB 094H,094H,88h ; 6 6 5 -
DB 74H,74H,63H,63H ; 4 4 3 3
DB 52H,52H,48h ; 2 2 1-
END
⑸ 单片机，用一个蜂鸣器可以演奏出音乐吗
当然可以了，以下是兰花草的音乐播放程序，你可听听看。
我用Proteus仿真过了，可行。你也可以试试看。
SPK EQU P1.2 ;位定义
ORG 0
LJMP START
ORG 0030H ;伪指令，指定程序从0030H开始存放
START:
MOV R3,#00H ;R3清零（作为查表偏移）
NEXT: MOV A,R3
MOV DPTR,#TABLE ;查表
MOVC A,@A+DPTR
JZ START ;如果A是0就重来
MOV R7,A ;R7是查表的来的代码字节
INC R3 ;读下一个代码字节
MOV A,R3
MOVC A,@A+DPTR
MOV R2,A
ACALL SONG
INC R3
SJMP NEXT;歌曲播放子程序
SONG:
MOV A,R2 ;取出节拍
RL A ;左移节拍
JNZ KEEP ;如果节拍为0就让它等于1
MOV A,#01H
KEEP:
MOV R2,A
REPEAT:
ACALL EIGHTH
DJNZ R2,REPEAT
RET;产生1/8拍延时子程序
EIGHTH: MOV A,R7 ;查表取出廷时参数,保存到R4
MOV DPTR,#DELAY_T
MOVC A,@A+DPTR
MOV R4,A
MOV A,R7 ;查表取出1/8拍周期数,保存到R5
MOV DPTR,#S_PARA
MOVC A,@A+DPTR
MOV R5,A
NEXTCYC:
ACALL SOUND
DJNZ R5,NEXTCYC
RET
;=== 发声子程序 ===
SOUND: SETB SPK
ACALL SDELAY
CLR SPK
ACALL SDELAY
RET;延时子程序
SDELAY: MOV A,R4 ; 廷时值在R4内
MOV R0,A
XL2: MOV R1,#03H
DL1: NOP
DJNZ R1,DL1
DJNZ R0,XL2
RET
;1/8拍周期表
S_PARA:DS 1DH
DB 15H,16H,00
DB 19H,00H,1CH,00H,1FH,21H,00H,25H
DB 00H,29H,2CH,00H,31H,34H,37H,00H
DB 3EH,41H,00H,49H,00H,52H,57H,00H
DB 62H
;延时参数表
DELAY_T:DS 1DH
DB 7EH,77H,00H
DB 6AH,00H,5EH,00H,54H,4FH,00H,46H
DB 00H,3FH,3BH,00H,35H,32H,2FH,00H
DB 2AH,27H,00H,23H,00H,1FH,1DH,0C0H
DB 1AH
;歌曲表
TABLE:DW 2202H,2902H,2902H,2902H,2906H,2702H ;我从山中来
DW 2502H,2702H,2502H,2402H,2208H ;带着兰花草
DW 2E02H,2E02H,2E02H,2E02H,2E06H,2C02H ;种在小园中
DW 2902H,2C02H,2D02H,2A02H,2908H ;祈祷花开早
DW 2902H,2E02H,2E02H,2C02H,2906H,2702H ;一日看三回
DW 2502H,2702H,2502H,2402H,2206H,1D02H ;看得花时过
DW 1D02H,2502H,2502H,2402H,2206H,2902H ;兰花却依然
DW 2702H,2502H,2402H,2002H,2208H ;苞也无一个
DW 0000H
END
⑹ 单片机音乐编程
<单片机音乐程序的设计图>
硬件连接说明:
随便找一个仿真机或者什么单片机实验板,只要能工作的就行,将程序输入,运行,然后找个音箱(你计算机旁边应当就有一对吧)拨出插头,插头的前端接在P1.0上,后面部分找根线接单片机的地,就应当有声了,然后怎么改进硬件连接就是你的事了....
音乐程序汇编代码代码1 -------------Voice.asm--------------------------
ORG 0000H
LJMP START
ORG 000BH
INC 20H ;中断服务,中断计数器加1
MOV TH0,#0D8H
MOV TL0,#0EFH ;12M晶振,形成10毫秒中断
RETI
START:
MOV SP,#50H
MOV TH0,#0D8H
MOV TL0,#0EFH
MOV TMOD,#01H
MOV IE,#82H
MUSIC0:
NOP
MOV DPTR,#DAT ;表头地址送DPTR
MOV 20H,#00H ;中断计数器清0
MOV B,#00H ;表序号清0
MUSIC1:
NOP
CLR A
MOVC A,@A+DPTR ;查表取代码
JZ END0 ;是00H,则结束
CJNE A,#0FFH,MUSIC5
LJMP MUSIC3
MUSIC5:
NOP
MOV R6,A
INC DPTR
MOV A,B
MOVC A,@A+DPTR ;取节拍代码送R7
MOV R7,A
SETB TR0 ;启动计数
MUSIC2:
NOP
CPL P1.0
MOV A,R6
MOV R3,A
LCALL DEL
MOV A,R7
CJNE A,20H,MUSIC2 ;中断计数器(20H)=R7否?
;不等,则继续循环
MOV 20H,#00H ;等于,则取下一代码
INC DPTR
; INC B
LJMP MUSIC1
MUSIC3:
NOP
CLR TR0 ;休止100毫秒
MOV R2,#0DH
MUSIC4:
NOP
MOV R3,#0FFH
LCALL DEL
DJNZ R2,MUSIC4
INC DPTR
LJMP MUSIC1
END0:
NOP
MOV R2,#64H ;歌曲结束,延时1秒后继续
MUSIC6:
MOV R3,#00H
LCALL DEL
DJNZ R2,MUSIC6
LJMP MUSIC0
DEL:
NOP
DEL3:
MOV R4,#02H
DEL4:
NOP
DJNZ R4,DEL4
NOP
DJNZ R3,DEL3
RET
NOP
DAT:
db 26h,20h,20h,20h,20h,20h,26h,10h,20h,10h,20h,80h,26h,20h,30h,20h
db 30h,20h,39h,10h,30h,10h,30h,80h,26h,20h,20h,20h,20h,20h,1ch,20h
db 20h,80h,2bh,20h,26h,20h,20h,20h,2bh,10h,26h,10h,2bh,80h,26h,20h
db 30h,20h,30h,20h,39h,10h,26h,10h,26h,60h,40h,10h,39h,10h,26h,20h
db 30h,20h,30h,20h,39h,10h,26h,10h,26h,80h,26h,20h,2bh,10h,2bh,10h
db 2bh,20h,30h,10h,39h,10h,26h,10h,2bh,10h,2bh,20h,2bh,40h,40h,20h
db 20h,10h,20h,10h,2bh,10h,26h,30h,30h,80h,18h,20h,18h,20h,26h,20h
db 20h,20h,20h,40h,26h,20h,2bh,20h,30h,20h,30h,20h,1ch,20h,20h,20h
db 20h,80h,1ch,20h,1ch,20h,1ch,20h,30h,20h,30h,60h,39h,10h,30h,10h
db 20h,20h,2bh,10h,26h,10h,2bh,10h,26h,10h,26h,10h,2bh,10h,2bh,80h
db 18h,20h,18h,20h,26h,20h,20h,20h,20h,60h,26h,10h,2bh,20h,30h,20h
db 30h,20h,1ch,20h,20h,20h,20h,80h,26h,20h,30h,10h,30h,10h,30h,20h
db 39h,20h,26h,10h,2bh,10h,2bh,20h,2bh,40h,40h,10h,40h,10h,20h,10h
db 20h,10h,2bh,10h,26h,30h,30h,80h,00H
END
音乐程序汇编代码代码2 -------------Voice1.asm--------------------------
;标题 '八月桂花香'发声程序
;摘要 详见'无线电'92年3期
;作者 周振安
ORG 0000H
LJMP START
ORG 000BH
INC 20H ;中断服务,中断计数器加1
MOV TH0,#0D8H
MOV TL0,#0EFH ;12M晶振,形成10毫秒中断
RETI
START:
MOV SP,#50H
MOV TH0,#0D8H
MOV TL0,#0EFH
MOV TMOD,#01H
MOV IE,#82H
MUSIC0:
NOP
MOV DPTR,#DAT ;表头地址送DPTR
MOV 20H,#00H ;中断计数器清0
MOV B,#00H ;表序号清0
MUSIC1:
NOP
CLR A
MOVC A,@A+DPTR ;查表取代码
JZ END0 ;是00H,则结束
CJNE A,#0FFH,MUSIC5
LJMP MUSIC3
MUSIC5:
NOP
MOV R6,A
INC DPTR
MOV A,B
MOVC A,@A+DPTR ;取节拍代码送R7
MOV R7,A
SETB TR0 ;启动计数
MUSIC2:
NOP
CPL P1.0
MOV A,R6
MOV R3,A
LCALL DEL
MOV A,R7
CJNE A,20H,MUSIC2 ;中断计数器(20H)=R7否?
;不等,则继续循环
MOV 20H,#00H ;等于,则取下一代码
INC DPTR
; INC B
LJMP MUSIC1
MUSIC3:
NOP
CLR TR0 ;休止100毫秒
MOV R2,#0DH
MUSIC4:
NOP
MOV R3,#0FFH
LCALL DEL
DJNZ R2,MUSIC4
INC DPTR
LJMP MUSIC1
END0:
NOP
MOV R2,#64H ;歌曲结束,延时1秒后继续
MUSIC6:
MOV R3,#00H
LCALL DEL
DJNZ R2,MUSIC6
LJMP MUSIC0
DEL:
NOP
DEL3:
MOV R4,#02H
DEL4:
NOP
DJNZ R4,DEL4
NOP
DJNZ R3,DEL3
RET
NOP
⑺ 如何确定单片机音乐播放的音律和节拍计算
你是想用单片机编程，来播放曲子是吧。那往下看：
1.确定每一拍的时间，一般是一分钟多少拍，确定一拍的时间是多少秒，确定每个音符的音长。
2.每个音符的音高，用十二平均律确定音高就可了。下面是音高与频率的对应关系。
http://wenku..com/view/e1f7a551f01dc281e53af02a.html
红色的部分是middle C的频率。
3.音色选择，也就是乐器的选择，这个比较复杂，很难说清楚，如果这方面有问题，可给我发消息。先用c语言的beep函数试着编写一下。
⑻ 想做个单片机音乐频谱 但是我不知道如何从声音中提取出各个频点的大小 本人高一 太难的算法有可能看
只能用傅立叶变换，求频谱。
这算法，比较复杂，普通的单片机，难做。
⑼ 如何将音乐中的节拍提取出来
用节拍器 .
那个比较准
可以在电脑下载
也可以用钱买.平均80元/个
⑽ 51单片机音律和节拍是怎么送到P2.0口的
51单片机产生音乐的原理是每个节拍的持续时间内，将定时的定时时间设为周期的一半，定时器时间到就产生中断，将P2.0口的状态取反一次。例如，声音频率是1KHZ，周期是1ms，定时500us就可以了 。由于音乐的频率是有规律的，可以将不同的音符的定时器初值制成表格，主程序根据乐谱内容查表，即可得到频率有规律的方波，推动扬声器发声即可。