錢包選股指標源碼

1. 請老師寫一個同時出現錢包買點鑽石買點的通達信選股公式

可以編寫但需要你提供全部公式代碼才可以編寫。

2. 求助，如何將改成選股公式

如何將技術指標修改成選股公式[通達信]

希望讀到這個帖子的人能夠學會自己修改選股公式，
用公式的人永遠是讓人玩的（你不知道人家是怎麼想的）
寫公式的人永遠是玩人的人（我知道就是不告訴你原理，）
當然用公式的也有玩寫公式的人的時候（我見過求人改公式的把一個公式的源碼拆成好幾段讓人家改）
沒有貶低別人的意思，用公式知其然不知其所以然，當你能夠看懂公式的源碼的時候，你就會知道公式是干什麼的，
一個在小機構工作過的人說過其實指標的運算模式就是那麼幾個，不同的就是參數的設置不一樣，
指標公式的原理就像一個人，那些線，顏色，符號，就是人的衣服，這個帖子是在網上找的希望對大家有用

當指標編寫不出來的時候，再請教梅花皇後這樣也許會更好些，也讓梅花皇後少做些無用功
騰出時間來交流一些更有價值的東西，

股票指標如果你肯花上一周的時間來熟悉那些常用的函數，應該大概明白指標的意思，

在附件當中我會上三個附件《編寫技術指標1000問》是關於技術指標的編寫當中的常見的問題

一品抄底】，是個副圖指標，既有線性輸出信號，也有買點提示信號，輸出類別眾多，就不是一個單獨的選股指標。如何修改、拆分出自己需要的【底部】選股信號，成為一個單獨的選股指標呢？如果還需要將【深坑】的信號，也單獨設置為選股指標，又該如何修改呢？在此先當做一個問題吧，繼續看了後面（二）、（三）小節的引路，相信你自己來就行了！
{一品抄底----品茶緣編寫，通用副圖指標}
TYP := (HIGH + LOW + CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
A:=REF(C,1);
RSI:=SMA(MAX(C-A,0),6,1)/SMA(ABS(C-A),6,1)*100;
A1:=(C/MA(C,5)-1)*100<-10;
A2:=(C/MA(C,13)-1)*100<-10;
A3:=(C/MA(C,34)-1)*100<-15;
A4:=RSI<18;
A5:=CCI<-120;
A6:=COUNT(ABS(C/REF(C,1)-1)*100>=6,30)>=1;
底部:A1 AND A2 AND A3 AND A4 AND A5 AND A6,COLOR00FFFF,LINETHICK2;
CDSJ:=BARSLAST(底部);
ZF:=(C/REF(C,1)-1)*100;
深坑:IF(BETWEEN(CDSJ,0,5) AND L<=REF(C,CDSJ) AND ZF<=-5,-0.5,0),COLORFF0000,LINETHICK2;
機會:IF(CDSJ<=7 AND L<=REF(C,CDSJ),0.5,0),COLOR00FF00;
尋找選股信號的來源

所謂選股信號，多數都是屬於將已有的指標公式中具有買點類的信號特徵「剝離」出來。那麼，在指標中該保留哪些有用的源碼，刪除哪些無關的源碼呢？尋找選股信號的來源，就是最主要的過程。
尋找選股信號來源的方法，一般都是遵循從後往前尋找的原則。
具體步驟是：先找到發出指標信號的那行代碼，然後查看該行代碼中的所有條件，需要用到上面哪些源碼，再從後往前一一對應尋找出來；而其他無關的條件、修飾符號源碼，均可刪除。
舉例3：（本例子參考大慶老楊先生帖子，略有改動）
{股市馬經----副圖指標，源碼來自網路}
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A2:=(黑馬線-REF(黑馬線,1))/REF(黑馬線,1)*100;
A3:=EMA(C,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
A5:=(HHV(H,60)-C)/(HHV(H,60)-LLV(L,60))*100;
DRAWTEXT(FILTER(REF(黑馬線,1)>90 AND A2<0,7),黑馬線,'跑'),COLOR00FF00;
DRAWTEXT(CROSS(A1,黑馬線)AND 黑馬線<A5,黑馬線,'黑馬');
DRAWTEXT(CROSS(黑馬線,A5)AND 趨勢線<80,黑馬線,'追漲');
DRAWTEXT(CROSS(趨勢線,0)AND 黑馬線<40,5,'大黑馬');
底部:(A2<-10 AND A2>REF(A2,1))*25,colorred;
DRAWICON(底部 AND A3>REF(A3,1),25,4);
機會來臨:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1),COLORF00FF0;
大勢已去:IF(CROSS(黑馬線,A1)AND 黑馬線>70 AND 趨勢線>80,90,100),COLORFF0000;
公式中涉及「買」的信號有黑馬、追漲、大黑馬、底部和機會來臨五個明顯的，另外還有一個畫圖標信號。

假如我們提取其中的【機會來臨】，仔細分析後，就是一句話：
機會來臨:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1);
這個可看作簡單提取。

如果提取【大黑馬】的話，從後向前推，涉及趨勢線和黑馬線兩個定義，這部分都有用：
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
DRAWTEXT(CROSS(趨勢線,0) AND 黑馬線<40,5,'大黑馬');

（三）修改選股指標的方法

根據以上選股公式的特徵，結合尋找選股信號來源的方法，自己動手修改選股信號，應該就沒有太大的難度了！

舉例4：繼續承接上面（二）的例子。
修改步驟：
①先將線性輸出的A1、黑馬線、A4、趨勢線均限制輸出，方法很簡單，就是在他們的冒號後面直接加上等號=；
②再刪去修飾符LINETHICK2,COLOR6600FF：
③將本來是文字輸出的「黑馬線」修改成信號輸出；先將「黑馬線」三個字移動到最前面，並加上冒號：；然後保留符合黑馬線的限制條件CROSS(趨勢線,0) AND 黑馬線<40；同時刪除其餘無關的代碼，包括文字輸出函數DRAWTEXT、位置、括弧（）等。
修改成選股指標後的源碼如下：
A1:=3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:=EMA(A1,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:=(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2));
大黑馬:CROSS(趨勢線,0) AND 黑馬線<40;

舉例5：
下面附圖指標【大三浪】中，如何選出出現「買」字提示信號的選股指標？
{大三浪----理想論壇一品茶緣編寫，通用副圖指標}
{大三浪指標使用說明:
均線粘合且多頭,長期未漲庄吸籌;
目標鎖定先跟蹤,出擊買入等豐收!}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
多頭粘合:IF(多頭 AND 粘合,1,0),COLORFF00FF,POINTDOT,LINETHICK0;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標:IF(多頭 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
跟蹤:IF(目標,BARSLAST(CROSS(目標,0))+1,0),COLOR00FF00,POINTDOT,LINETHICK2;
出擊:IF(CROSS(0.1,目標) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
MJSJ:=BARSLAST(出擊>0);
漲幅:IF(MJSJ<=120,(C/REF(C,MJSJ)-1)*100,0),COLOR0000FF,POINTDOT,LINETHICK0;
日漲:IF(MJSJ<=120,漲幅/MJSJ,0),COLORFFFFFF,POINTDOT,LINETHICK0;
TPX:=MIN(MA65*1.15,MA21*1.13);
突破:IF(CROSS(C,TPX) AND 粘合 AND MA65>REF(MA65,1),10,0),COLOR0000FF,LINETHICK2;
{以下設置副圖顯示方式}
STICKLINE(多頭粘合,0,1,8,0),COLORFF00FF;
STICKLINE(庄股,0,MACD*10,8,0),COLORFFFF00;
DRAWTEXT(出擊=8,10,'★買'),COLOR00FFFF;
VERTLINE(CROSS(漲幅,20) AND COUNT(CROSS(漲幅,20),MJSJ)=1,2),COLOR0000FF;

根據選股指標的步驟，一步一步來：
①首先找到出現「★買」提示的一行代碼，發現她其實就是「出擊」的信號；
②從後往前，找到「出擊」信號的條件，發現他與「目標」、MACD有關；
再次往前尋找，又發現「目標」信號的條件，與「多頭」、「粘合」、「庄股」三個條件有關，由此，保留相關條件代碼，其餘刪除，如下：
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標:IF(多頭 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
出擊:IF(CROSS(0.1,目標) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
③限制輸出數量，只保留「出擊」信號的輸出，其他的輸出信號均加上等號=加以限制輸出；
④刪除多餘的修飾符號，如：COLORFFFF00,POINTDOT,LINETHICK0等。
⑤IF格式也可簡化，只保留需要的條件，輸出信號自動為1。「出擊」兩字也可修改為「買」。
修改完最後保留的源碼如下：

{大三浪----選股指標}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:=COUNT(MACD<0,10)=10;
目標:=IF(多頭 AND 粘合 AND 庄股,5,0);
買:CROSS(0.1,目標) AND CROSS(MACD,0);

導入選股指標的途徑
①修改完後的選股指標源碼，想做成選股指標，並非放在指標系統之下的【技術指標】分類，一般是放入【條件選股】分類；便於設置預警、自動選股。
②還可將選股指標加入交易系統中，但需要注意的是：輸出信號必須為英文單詞的買入ENTERLONG、賣出EXITLONG信號。在應用時，飛狐軟體輸入該交易系統指標名稱，即可在主圖自動顯示買賣信號的提示。
源碼如下：
ENTERLONG:CROSS(MA(C,3),MA(C,8));----表示輸出多頭買入信號。
EXITLONG:CROSS(MA(C,8),MA(C,3));----表示輸出空頭賣出信號。

3. 在通達信軟體中如何設置用9號圖標選股有些輔圖軟體中會出現錢包（即9號圖標），如何選出帶有錢包的股標

在公式代碼中找到

DRAWICON這個函數

例如下面這句

DRAWICON(CROSS(C,MA(C,60)),L,9);

意思是說收盤價金叉60日均線在最低價畫9號圖標

圖中效果

選股只需要CROSS(C,MA(C,60));收盤價金叉60日均線這句代碼;就可以了

DRAWICON(,,);一共有算個參數,第一個逗號前就是條件,可以是變數也可以是一段公式代碼.第二個參數是要顯示的位置,第三個就是圖標序號了.

找到DRAWICON這個函數的代碼,括弧里有9的就找到選股條件來.技術指標改選股指標需要把畫線類函數都刪除掉,並且只保留最後一個輸出.

這個很簡單改幾回就會了.

4. 求通達信公式高手將指標源碼拆解成兩個通達信選股公式，重酬

1、粉色柱出現第一天選股買入股票：
V1:=(C*2+H+L)/4*10;
V2:=EMA(V1,13)-EMA(V1,34);
V3:=EMA(V2,5);
V4:=2*(V2-V3)*5.5;
主力進:=IF(V4>=0,V4,0),COLORFF00FF;
V11:=3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA(SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1),3,1);
趨勢線:=EMA(V11,3);
XG:REF(主力進 AND 趨勢線<13,1)=0 AND 主力進 AND 趨勢線<13=1;

2、綠柱出現第一天預警賣出股票：
V8:=(INDEXC*2+INDEXH+INDEXL)/4;
V9:=EMA(V8,13)-EMA(V8,34);
VA:=EMA(V9,3);
VB:=(V9-VA)/2;
大盤資金撤走:=IF(VB<=0,VB,0),COLORGREEN;
V11:=3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA(SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1),3,1);
趨勢線:=EMA(V11,3);
賣出:REF(大盤資金撤走 AND 趨勢線>90,1)=0 AND 大盤資金撤走 AND 趨勢線>90=1;

不為別的，為了你的高分，必須滴！不許食言啊！

5. 求高手編寫通達信選股指標

籌碼集中度SCR<5的選股公式:
P1:=90;
A:=P1+(100-P1)/2;
B:=(100-P1)/2;
CC:=COST(A);
DD:=COST(B);
SCR:((CC-DD)/(CC+DD)*100/2)<5;

6. 通達信主圖指標源碼，求老師看有沒有未來，並幫改成選股和預警公式，謝謝

(1)無未來函數
(2)選股公式如下(買入)：
VAR1:=(100 - ((90 * (HHV(HIGH,14) - CLOSE)) / (HHV(HIGH,14) - LLV(LOW,14))));
VAR2:=(100 - ((90 * (HHV(HIGH,14) - CLOSE)) / (HHV(HIGH,14) - LLV(LOW,14))));
VAR3:=(100 - MA(((100 * (HHV(HIGH,6) - CLOSE)) / (HHV(HIGH,6) - LLV(LOW,6))),34));
DIR1:=ABS(CLOSE-REF(CLOSE,5));
VIR1:=SUM(ABS(CLOSE-REF(CLOSE,1)),5);
ER1:=DIR1/VIR1;
CS1:=ER1*(0.8-2/8)+2/8;
CQ1:=CS1*CS1;
DIR2:=ABS(CLOSE-REF(CLOSE,10));
VIR2:=SUM(ABS(CLOSE-REF(CLOSE,1)),10);
ER2:=DIR2/VIR2;
CS2:=ER2*(0.8-2/24)+2/24;
CQ2:=CS2*CS2;
CROSS(VAR2,MA(VAR3,6));

7. 請高手將下面的【大資金進場】指標公式改寫成選股器，特急，謝謝！ 源代碼如下：

VAR1:=REF(LOW,1);
VAR2:=(SMA(ABS(LOW-VAR1),13,1))/(SMA(MAX(LOW-VAR1,0),13,1))*4;
VAR3:=EMA(VAR2,13);
VAR4:=LLV(LOW,34);
VAR5:=EMA(IF(LOW
REF(VOL,1) AND CLOSE>REF(CLOSE,1);
XG:VAR8 AND COUNT(VAR8,18)=1;

8. 通達信根據指標源碼怎樣編選股公式

VAR3:=(CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*100;
VAR4:=(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100;
VAR5:=(CLOSE-MA(CLOSE,32))/MA(CLOSE,32)*100;
VAR6:=(VAR3+VAR4+VAR5)/3;
VAR7:=EMA(VAR6,5);
ZB:=EMA(EMA(VAR3,5),5)*3;
VAR8:=IF(VAR6<=-20,10,0);
VAR9:=HHV(VAR8,10);
VARA:=IF(VAR9 AND CROSS(MA(CLOSE,3),MA(CLOSE,5)),20,0);
准備:=VAR8=10 AND FILTER(VAR8=10,5);
一定要買:=VARA=20;
VARF:=100-3*SMA((CLOSE-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1)+2*SMA(SMA((CLOSE-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1),15,1);
VAR10:=100-3*SMA((OPEN-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1)+2*SMA(SMA((OPEN-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1),15,1);
VAR11:=VARF<REF(VAR10,1) AND VOL>REF(VOL,1) AND CLOSE>REF(CLOSE,1);
莊家異動:=VAR11 AND COUNT(VAR11,30)=1;
錢包:=(ZIG(3,5)>REF(ZIG(3,5),1)) AND (REF(ZIG(3,5),1)<=REF(ZIG(3,5),2)) AND (REF(ZIG(3,5),2)<=REF(ZIG(3,5),3));
XG:(准備 OR 一定要買 OR 莊家異動) AND 錢包;

=======================
{單獨出現}
VAR3:=(CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*100;
VAR4:=(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100;
VAR5:=(CLOSE-MA(CLOSE,32))/MA(CLOSE,32)*100;
VAR6:=(VAR3+VAR4+VAR5)/3;
VAR7:=EMA(VAR6,5);
ZB:=EMA(EMA(VAR3,5),5)*3;
VAR8:=IF(VAR6<=-20,10,0);
VAR9:=HHV(VAR8,10);
VARA:=IF(VAR9 AND CROSS(MA(CLOSE,3),MA(CLOSE,5)),20,0);
准備:=VAR8=10 AND FILTER(VAR8=10,5);
一定要買:=VARA=20;
VARF:=100-3*SMA((CLOSE-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1)+2*SMA(SMA((CLOSE-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1),15,1);
VAR10:=100-3*SMA((OPEN-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1)+2*SMA(SMA((OPEN-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1),15,1);
VAR11:=VARF<REF(VAR10,1) AND VOL>REF(VOL,1) AND CLOSE>REF(CLOSE,1);
莊家異動:=VAR11 AND COUNT(VAR11,30)=1;
錢包:=(ZIG(3,5)>REF(ZIG(3,5),1)) AND (REF(ZIG(3,5),1)<=REF(ZIG(3,5),2)) AND (REF(ZIG(3,5),2)<=REF(ZIG(3,5),3));
XG:准備 OR 一定要買 OR 莊家異動 OR 錢包;

9. 哪位高手可以把通達信指標公式改成選股公式 源碼如下：V6:=CLOSE/REF(CLOSE,3)>=1.1; V7:=BACKSET(V6,3);

其實你不用發別人的什麼源碼,你只將你的想法說出來,就會有人幫你
-----------------------------------------------------------------------------------
看你發了上面兩句代碼,估計你沒有看懂源碼是什麼意思,看不懂的東西,最好是別去看他,不如自己想自己的,根據自己的想法做的東西(自己不會做,可以請人幫忙的),才知道是怎麼回事