『壹』 匯編語言設計的單片機4*4矩陣鍵盤
/* 實驗目的：1.掌握鍵盤掃描的原理以及十/十六進制的轉換
* 2.了解單片機輸入和輸出的過程,以及如何對數據進行採集的
* 實驗內容：鍵盤渣凱上對應有16個按鍵,從0到F,按下相應的鍵會在數碼管上顯示相應的數字,
* 其中K0到K15是採用4*4的方式連接的
*/
;******************************************************************
; 0 1 2 3 ---P20
; 4 5 6 7 ---P21
; 8 9 A B ---P22
; C D E F ---P23
; | | | |
; P24 P25 P26 P27
;******************************************************************
ORG 0000h
LJMP MAIN
ORG 0030h
MAIN:
MOV DPTR,#TAB ;將表頭放入DPTR
LCALL KEY ;調用鍵盤掃描程序
MOVC A,@A+DPTR ;查表後將鍵值送入ACC
MOV P0,A ;將Acc值送入P0口
CLR P1.3 ;開顯示
LJMP MAIN ;返回調用子程序反復循環顯示
KEY: LCALL KS ;調用檢測按鍵子程序
JNZ K1 ;有鍵按下繼續
LCALL DELAY2 ;無鍵按下調用延時去抖動程序
AJMP KEY ;返回繼續檢測有無按鍵按下
K1: LCALL DELAY2
LCALL DELAY2 ;有鍵按下繼續延時去抖動
LCALL KS ;再一次調用檢測按鍵程序頃脊
JNZ K2 ;確認有按下進行下一步
AJMP KEY ;無鍵按下返回繼續檢測
K2: MOV R2,#0EFH ;將掃描值送入 R2暫存
MOV R4,#00H ;將第一列的列值00H送入R4暫存,R4用於存放列值。
K3: MOV P2,R2 ;將R2的值送入P2口
L6: JB P2.0,L1 ;P2.0等於1跳轉到L1
MOV A,#00H ;將第一行的行雀梁滲值00H送入ACC
AJMP LK ;跳轉到鍵值處理程序
L1: JB P2.1,L2 ;P2.1等於1跳轉到L2
MOV A,#04H ;將第二行的行值送入ACC
AJMP LK ;跳轉到鍵值理程序進行鍵值處理
L2: JB P2.2,L3 ;P1.2等於1跳轉到L3
MOV A,#08H ;將第三行的行值送入ACC
AJMP LK ;跳轉到鍵值處理程序
L3: JB P2.3,NEXT ;P2.3等於1跳轉到NEXT處
MOV A,#0cH ;將第四行的行值送入ACC
LK: ADD A,R4 ;行值與列值相加後的鍵值送入A
PUSH ACC ;將A中的值送入堆棧暫存
K4: LCALL DELAY2 ;調用延時去抖動程序
LCALL KS ;調用按鍵檢測程序
JNZ K4 ;按鍵沒有松開繼續返回檢測
POP ACC ;將堆棧的值送入ACC
RET
NEXT:
INC R4 ;將列值加一
MOV A,R2 ;將R2的值送入A
JNB ACC.7,KEY ;掃描完成跳至KEY處進行下一回合的掃描
RL A ;掃描未完成將A中的值右移一位進行下一列的掃描
MOV R2,A ;將ACC的值送入R2暫存
AJMP K3 ;跳轉到K3繼續
KS: MOV P2,#0FH ;將P2口高四位置0低四位值1
MOV A,P2 ;讀P2口
XRL A,#0FH ;將A中的值與A中的值相異或
RET ;子程序返回
DELAY2: ;40ms延時去抖動子程序8*FA*2=40ms
MOV R5,#08H
L7: MOV R6,#0FAH
L8: DJNZ R6,L8
DJNZ R5,L7
RET
TAB:
DB 0C0H;0
DB 0F9H;1
DB 0A4H;2
DB 0B0H;3
DB 099H;4
DB 092H;5
DB 082H;6
DB 0F8H;7
DB 080H;8
DB 090H;9
DB 088H;A
DB 083H;b
DB 0C6H;C
DB 0A1H;d
DB 086H;E
DB 08EH;F
END
『貳』 單片機矩陣式鍵盤顯示設計中,如何處理多個按鍵同時按下的情況
矩陣鍵盤悉橘陪有多種鍵盤演算法，如果是行列掃描的話，多個按鍵同時按下是可以得到所有的鍵值，如果是線反轉法的話，就會有誤判的可能。
行列掃描的話，睜蠢一次只掃描一行按鍵，而且對伍源應行的按鍵的狀態也會通過互相獨立的IO得到。