製作選股指標源碼

⑴ 有請大俠幫忙做個選股指標

MTR:=EXPMEMA(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(REF(CLOSE,1)-LOW)),14);
HD :=HIGH-REF(HIGH,1);
LD :=REF(LOW,1)-LOW;
DMP:=EXPMEMA(IF(HD>0&&HD>LD,HD,0),14);
DMM:=EXPMEMA(IF(LD>0&&LD>HD,LD,0),14);
PDI:=DMP*100/MTR;
MDI:=DMM*100/MTR;
ADX:=EXPMEMA(ABS(MDI-PDI)/(MDI+PDI)*100,6);
ADXR:=EXPMEMA(ADX,MM);
XG:CROSS(PDI,MDI)AND CROSS(PDI,ADX)AND CROSS(PDI,ADXR);

⑵ 指標公式如何改寫成選股條件公式

【一品抄底】，是個副圖指標，既有線性輸出信號，也有買點提示信號，輸出類別眾多，就不是一個單獨的選股指標。如何修改、拆分出自己需要的【底部】選股信號，成為一個單獨的選股指標呢？如果還需要將【深坑】的信號，也單獨設置為選股指標，又該如何修改呢？在此先當做一個問題吧，繼續看了後面（二）、（三）小節的引路，相信你自己來就行了！
{一品抄底----創幻論壇一品茶緣編寫，通用副圖指標}
TYP := (HIGH + LOW + CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
A:=REF(C,1);
RSI:=SMA(MAX(C-A,0),6,1)/SMA(ABS(C-A),6,1)*100;
A1:=(C/MA(C,5)-1)*100<-10;
A2:=(C/MA(C,13)-1)*100<-10;
A3:=(C/MA(C,34)-1)*100<-15;
A4:=RSI<18;
A5:=CCI<-120;
A6:=COUNT(ABS(C/REF(C,1)-1)*100>=6,30)>=1;
底部:A1 AND A2 AND A3 AND A4 AND A5 AND A6,COLOR00FFFF,LINETHICK2;
CDSJ:=BARSLAST(底部);
ZF:=(C/REF(C,1)-1)*100;
深坑:IF(BETWEEN(CDSJ,0,5) AND L<=REF(C,CDSJ) AND ZF<=-5,-0.5,0),COLORFF0000,LINETHICK2;
機會:IF(CDSJ<=7 AND L<=REF(C,CDSJ),0.5,0),COLOR00FF00;
尋找選股信號的來源

所謂選股信號，多數都是屬於將已有的指標公式中具有買點類的信號特徵「剝離」出來。那麼，在指標中該保留哪些有用的源碼，刪除哪些無關的源碼呢？尋找選股信號的來源，就是最主要的過程。
尋找選股信號來源的方法，一般都是遵循從後往前尋找的原則。
具體步驟是：先找到發出指標信號的那行代碼，然後查看該行代碼中的所有條件，需要用到上面哪些源碼，再從後往前一一對應尋找出來；而其他無關的條件、修飾符號源碼，均可刪除。
舉例3：（本例子參考大慶老楊先生帖子，略有改動）
{股市馬經----副圖指標，源碼來自網路}
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A2:=(黑馬線-REF(黑馬線,1))/REF(黑馬線,1)*100;
A3:=EMA(C,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
A5:=(HHV(H,60)-C)/(HHV(H,60)-LLV(L,60))*100;
DRAWTEXT(FILTER(REF(黑馬線,1)>90 AND A2<0,7),黑馬線,'跑'),COLOR00FF00;
DRAWTEXT(CROSS(A1,黑馬線)AND 黑馬線<A5,黑馬線,'黑馬');
DRAWTEXT(CROSS(黑馬線,A5)AND 趨勢線<80,黑馬線,'追漲');
DRAWTEXT(CROSS(趨勢線,0)AND 黑馬線<40,5,'大黑馬');
底部:(A2<-10 AND A2>REF(A2,1))*25,colorred;
DRAWICON(底部 AND A3>REF(A3,1),25,4);
機會來臨:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1),COLORF00FF0;
大勢已去:IF(CROSS(黑馬線,A1)AND 黑馬線>70 AND 趨勢線>80,90,100),COLORFF0000;
公式中涉及「買」的信號有黑馬、追漲、大黑馬、底部和機會來臨五個明顯的，另外還有一個畫圖標信號。

假如我們提取其中的【機會來臨】，仔細分析後，就是一句話：
機會來臨:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1);
這個可看作簡單提取。

如果提取【大黑馬】的話，從後向前推，涉及趨勢線和黑馬線兩個定義，這部分都有用：
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
DRAWTEXT(CROSS(趨勢線,0) AND 黑馬線<40,5,'大黑馬');

（三）修改選股指標的方法

根據以上選股公式的特徵，結合尋找選股信號來源的方法，自己動手修改選股信號，應該就沒有太大的難度了！

舉例4：繼續承接上面（二）的例子。
修改步驟：
①先將線性輸出的A1、黑馬線、A4、趨勢線均限制輸出，方法很簡單，就是在他們的冒號後面直接加上等號=；
②再刪去修飾符LINETHICK2,COLOR6600FF：
③將本來是文字輸出的「黑馬線」修改成信號輸出；先將「黑馬線」三個字移動到最前面，並加上冒號：；然後保留符合黑馬線的限制條件CROSS(趨勢線,0) AND 黑馬線<40；同時刪除其餘無關的代碼，包括文字輸出函數DRAWTEXT、位置、括弧（）等。
修改成選股指標後的源碼如下：
A1:=3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:=EMA(A1,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:=(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2));
大黑馬:CROSS(趨勢線,0) AND 黑馬線<40;

舉例5：
下面附圖指標【大三浪】中，如何選出出現「買」字提示信號的選股指標？
{大三浪----創幻論壇一品茶緣編寫，通用副圖指標}
{大三浪指標使用說明:
均線粘合且多頭,長期未漲庄吸籌;
目標鎖定先跟蹤,出擊買入等豐收!}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
多頭粘合:IF(多頭 AND 粘合,1,0),COLORFF00FF,POINTDOT,LINETHICK0;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標:IF(多頭 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
跟蹤:IF(目標,BARSLAST(CROSS(目標,0))+1,0),COLOR00FF00,POINTDOT,LINETHICK2;
出擊:IF(CROSS(0.1,目標) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
MJSJ:=BARSLAST(出擊>0);
漲幅:IF(MJSJ<=120,(C/REF(C,MJSJ)-1)*100,0),COLOR0000FF,POINTDOT,LINETHICK0;
日漲:IF(MJSJ<=120,漲幅/MJSJ,0),COLORFFFFFF,POINTDOT,LINETHICK0;
TPX:=MIN(MA65*1.15,MA21*1.13);
突破:IF(CROSS(C,TPX) AND 粘合 AND MA65>REF(MA65,1),10,0),COLOR0000FF,LINETHICK2;
{以下設置副圖顯示方式}
STICKLINE(多頭粘合,0,1,8,0),COLORFF00FF;
STICKLINE(庄股,0,MACD*10,8,0),COLORFFFF00;
DRAWTEXT(出擊=8,10,'★買'),COLOR00FFFF;
VERTLINE(CROSS(漲幅,20) AND COUNT(CROSS(漲幅,20),MJSJ)=1,2),COLOR0000FF; 根據選股指標的步驟，一步一步來：
①首先找到出現「★買」提示的一行代碼，發現她其實就是「出擊」的信號；
②從後往前，找到「出擊」信號的條件，發現他與「目標」、MACD有關；
再次往前尋找，又發現「目標」信號的條件，與「多頭」、「粘合」、「庄股」三個條件有關，由此，保留相關條件代碼，其餘刪除，如下：
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標:IF(多頭 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
出擊:IF(CROSS(0.1,目標) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
③限制輸出數量，只保留「出擊」信號的輸出，其他的輸出信號均加上等號=加以限制輸出；
④刪除多餘的修飾符號，如：COLORFFFF00,POINTDOT,LINETHICK0等。
⑤IF格式也可簡化，只保留需要的條件，輸出信號自動為1。「出擊」兩字也可修改為「買」。
修改完最後保留的源碼如下：
{大三浪----選股指標}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:=COUNT(MACD<0,10)=10;
目標:=IF(多頭 AND 粘合 AND 庄股,5,0);
買:CROSS(0.1,目標) AND CROSS(MACD,0); 導入選股指標的途徑
①修改完後的選股指標源碼，想做成選股指標，並非放在指標系統之下的【技術指標】分類，一般是放入【條件選股】分類；便於設置預警、自動選股。
②還可將選股指標加入交易系統中，但需要注意的是：輸出信號必須為英文單詞的買入ENTERLONG、賣出EXITLONG信號。在應用時，飛狐軟體輸入該交易系統指標名稱，即可在主圖自動顯示買賣信號的提示。
源碼如下：
ENTERLONG:CROSS(MA(C,3),MA(C,8));----表示輸出多頭買入信號。
EXITLONG:CROSS(MA(C,8),MA(C,3));----表示輸出空頭賣出信號。

⑶ 通達信軟體中，怎麼把公式製作成選股指標要步驟清晰過程

第一步：首先打開公式管理器、點擊條件選股、新建，書寫公式名稱（自己喜歡填什麼名稱都可以）、描述（同上），將要編寫的公式粘貼到公式編輯器。第二步驟：條件的尋找，例如：公式中的字選股，先找到公式中出現你要的字的地方，這種公式開頭會以DRAWTEXT函數開始。改函數括弧內（條件，文字顯示位置，文字）也就是說你要的條件就是括弧內的第一個逗號前的東西。第三步：找到選股時需要的條件值，將所有顯示（帶有「：」）改為不顯示（「：=」）。因為所有選股公式只能輸出1個條件，所以要先將公式中「：」改為「：=」。如果原顯示的值後面有線性或者顏色等等描述的一並刪除。例：將「買入」修改為選股公式：VAR1:MA(C,5),COLORRED;VAR2:MA(C,10),COLORGREEN,POINTDOT;VAR3:MA(C,20),COLORYELLOW;DRAWTEXT(CROSS(VAR1,VAR2),L-0.05,'買入');解：找到需要的條件式DRAWTEXT(CROSS(VAR1,VAR2),L-0.05,'買入');根據上述所知DRAWTEXT函數括弧內第一個逗號前為條件：CROSS(VAR1,VAR2)。從條件可知要完成這個條件需要VAR1和VAR2兩個值：VAR1:MA(C,5),COLORRED;VAR2:MA(C,10),COLORGREEN,POINTDOT;由於條件選股只能輸出一個條件因此首先將這兩個條件修改為不顯示並刪除線性和顏色描述：VAR1:=MA(C,5);VAR2:=MA(C,10);最後同條件合並：VAR1:=MA(C,5);VAR2:=MA(C,10);XG:CROSS(VAR1,VAR2);最後測試 通過 保存即可。簡單的基本步驟就是這樣！

⑷ 知道通達信這個指標源碼，怎樣編出這個指標的選股公式

通達信變數式表達為「：=」，通達信的輸出表達式為「：」，也就是沒有等號的變數就是輸出。
選股公式時只允許有一個變數輸出，輸出的條件就是你要選股的條件，其它作圖公式不能出現在選股公式中，因此上面的指標需要將所有作圖公式，如STICKLINE，DRAWICON等需要刪除或注釋掉；另外，變數後面如果有COLORRED、COLORFFCC66、LINETHICK3等情況，也是不允許的。
通過上述，可知，要將指標轉換成選股公式，則需把不需要的輸出變成變數，加個等號就可以了，把作圖公式注釋掉，如果你覺得作圖公式的條件才是選股公式，那麼把它拿出來作為唯一的輸出。

下面是以「條件」這個作為選股條件為例：

買:=IF("KDJ.J"<0,10,0);
條件:CROSS(9.9,買);
其它的部分沒用上，可以不要了。

如果要以XXX這一項作為選股公式，則可以這樣：

買:=IF("KDJ.J"<0,10,0);
條件:=CROSS(9.9,買);
VAR1:=(2*CLOSE+HIGH+LOW)/4;
VAR2:=LLV(LOW,5);
VAR3:=HHV(HIGH,5);
VAR4:=EMA((VAR1-VAR2)/(VAR3-VAR2)*100,5);
MA1:=MA(VAR4,2);
{AA:STICKLINE(VAR4>MA1,VAR4,MA1,6,1),COLORRED;}
{BBB:=STICKLINE(VAR4>MA1 AND REF(VAR4,1)<30,VAR4,MA1,6,1);}
{STICKLINE(VAR4<=MA1,VAR4,MA1,6,1),COLORFFCC66;}
{DRAWICON(CROSS(9.9,買),VAR4-12,4);}
{STICKLINE(CROSS(9.9,買),VAR4+5,MA1-4,6,1),COLORYELLOW;}
XXX:VAR4>MA1 AND REF(VAR4,1)<30;
加中括弧部分是注釋掉的部分，你也可以刪掉。
望採納!

⑸ 求高手編寫通達信選股指標

籌碼集中度SCR<5的選股公式:
P1:=90;
A:=P1+(100-P1)/2;
B:=(100-P1)/2;
CC:=COST(A);
DD:=COST(B);
SCR:((CC-DD)/(CC+DD)*100/2)<5;

⑹ 求教高人把通達信指標公式做成選股指標 源碼如下：

YC2:=REF(CLOSE,2);
YC:=REF(CLOSE,1);
TJ:=YC>=YC2;
YH:=MAX(YC2,YC);
YL:=MIN(YC2,YC);
TH:=MAX(YC,CLOSE);
TL:=MIN(YC,CLOSE);
GL:=TL;
GH1:=IF(TJ=0,MIN(YH,TH),YL);
GH:=IF(GH1<GL,GL,GH1);
XG:REF(GL,1) AND EVERY(GH>GL,2) AND C>O;

⑺ 求大神編寫一個通達信的指標源碼

可以編寫通達指標公式,60個交易日的最低點顯示紅鑽石後只要最高點大於前一個最高點就顯示數值,反之,60日內的最高點顯示綠鑽石並且後面只要小於前一日最低點且小於60個交易日最高點那天的最低點顯示綠色數字.效果如下圖.但你手工標注的數值後面的下跌顯示數值中的5不對當日並沒有比前日低，不符合你說的條件，放大一看就知道了。

⑻ 如何通過通達信指標編寫選股公式

市場上常用的股票交易客戶端具備公式選股系統。選股公式可能覺得有點玄學，實際上，這里的選股公式=excel函數 ，通過計算機能理解的語言與條件，快速選出自己想要的股票。股市中，技術指標並不是萬能的，所以選股公式也不是萬能的，它只能快速幫我們選出技術形態符合的股票，這樣可以提升我們獲利的概率，但並不能作為買入的唯一依據。

如果十項指標出現綠箭頭，那就趕緊賣出，當然一般按照多數人的趨勢，如果十項指標提示買入，就跟著買入，提示賣出，就要堅決賣出了。連增減持資金都可以在日線圖上顯示出來，比如，當我選擇增減持資金指標時，可以看到最近該股的大股東及董監高的增減持情況，這里的青色柱子就代表著當日有人減持，而且減持金額也標注了出來。

⑼ 通達信根據指標源碼怎樣編選股公式

VAR3:=(CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*100;
VAR4:=(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100;
VAR5:=(CLOSE-MA(CLOSE,32))/MA(CLOSE,32)*100;
VAR6:=(VAR3+VAR4+VAR5)/3;
VAR7:=EMA(VAR6,5);
ZB:=EMA(EMA(VAR3,5),5)*3;
VAR8:=IF(VAR6<=-20,10,0);
VAR9:=HHV(VAR8,10);
VARA:=IF(VAR9 AND CROSS(MA(CLOSE,3),MA(CLOSE,5)),20,0);
准備:=VAR8=10 AND FILTER(VAR8=10,5);
一定要買:=VARA=20;
VARF:=100-3*SMA((CLOSE-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1)+2*SMA(SMA((CLOSE-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1),15,1);
VAR10:=100-3*SMA((OPEN-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1)+2*SMA(SMA((OPEN-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1),15,1);
VAR11:=VARF<REF(VAR10,1) AND VOL>REF(VOL,1) AND CLOSE>REF(CLOSE,1);
莊家異動:=VAR11 AND COUNT(VAR11,30)=1;
錢包:=(ZIG(3,5)>REF(ZIG(3,5),1)) AND (REF(ZIG(3,5),1)<=REF(ZIG(3,5),2)) AND (REF(ZIG(3,5),2)<=REF(ZIG(3,5),3));
XG:(准備 OR 一定要買 OR 莊家異動) AND 錢包;

=======================
{單獨出現}
VAR3:=(CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*100;
VAR4:=(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100;
VAR5:=(CLOSE-MA(CLOSE,32))/MA(CLOSE,32)*100;
VAR6:=(VAR3+VAR4+VAR5)/3;
VAR7:=EMA(VAR6,5);
ZB:=EMA(EMA(VAR3,5),5)*3;
VAR8:=IF(VAR6<=-20,10,0);
VAR9:=HHV(VAR8,10);
VARA:=IF(VAR9 AND CROSS(MA(CLOSE,3),MA(CLOSE,5)),20,0);
准備:=VAR8=10 AND FILTER(VAR8=10,5);
一定要買:=VARA=20;
VARF:=100-3*SMA((CLOSE-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1)+2*SMA(SMA((CLOSE-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1),15,1);
VAR10:=100-3*SMA((OPEN-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1)+2*SMA(SMA((OPEN-LLV(LOW,75))/(HHV(HIGH,75)-LLV(LOW,75))*100,20,1),15,1);
VAR11:=VARF<REF(VAR10,1) AND VOL>REF(VOL,1) AND CLOSE>REF(CLOSE,1);
莊家異動:=VAR11 AND COUNT(VAR11,30)=1;
錢包:=(ZIG(3,5)>REF(ZIG(3,5),1)) AND (REF(ZIG(3,5),1)<=REF(ZIG(3,5),2)) AND (REF(ZIG(3,5),2)<=REF(ZIG(3,5),3));
XG:准備 OR 一定要買 OR 莊家異動 OR 錢包;

⑽ 股票指標選股器製作

M:=55;

N:=34;

LC:=REF(CLOSE,1);

RSI:=((SMA(MAX((CLOSE - LC),0),3,1) / SMA(ABS((CLOSE - LC)),3,1)) * 100);

FF:=EMA(CLOSE,3);

MA15:=EMA(CLOSE,21);

VAR1:=IF(YEAR>=2038 AND MONTH>=1,0,1);

VAR2:=REF(LOW,1)*VAR1;

VAR3:=SMA(ABS(LOW-VAR2),3,1)/SMA(MAX(LOW-VAR2,0),3,1)*100*VAR1;

VAR4:=EMA(IF(CLOSE*1.3,VAR3*10,VAR3/10),3)*VAR1;

VAR5:=LLV(LOW,30)*VAR1;

VAR6:=HHV(VAR4,30)*VAR1;

VAR7:=IF(MA(CLOSE,58),1,0)*VAR1;

VAR8:=EMA(IF(LOW<=VAR5,(VAR4+VAR6*2)/2,0),3)/618*VAR7*VAR1;

吸籌:=IF(VAR8>100,100,VAR8)*VAR1;

散戶:=100*(HHV(HIGH,M)-CLOSE)/(HHV(HIGH,M)-LLV(LOW,M));

RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;

K:=SMA(RSV,3,1);

D:=SMA(K,3,1);

J:=3*K-2*D;

莊家:=EMA(J,6);

XG:莊家>REF(莊家,1) AND 散戶<REF(散戶,1) AND 吸籌>2;