A. 有關ansys中一些基本命令的應用，高手求救
都是與體（volume）相關的命令。vsel，選擇體單元，VSEL,S,VOLUME,,1為談做螞選擇編號為1的含埋體單元。 vatt，對體單元賦予材料屬性。VATT,1,,1為賦予選擇的胡則體單元1號材料屬性。 vlist，列出選擇的體單元
B. 幫忙翻譯一下ansys命令流
!以下命令是劃分網格時自動生成的命令流，現分句解釋如下：
TYPE, 1 !設置單元類型為1
MAT, 1!設置材料屬性為1
REAL, !設置實常數，默認
ESYS, 0 !設置單元坐標系為0
SECNUM, !設置截面編號，默認
!*
MSHAPE,0,3D !設置劃分單元類型，為3D，即體單元
MSHKEY,1!設置劃分網格方法，1為採用映射網格劃分方法
!*
FLST,5,2,6,ORDE,2 ! 以下8句為軟體自己生成的命令，作用是選擇被劃分的體並自定義組件
FITEM,5,1
FITEM,5,-2
CM,_Y,VOLU
VSEL, , , ,P51X
CM,_Y1,VOLU
CHKMSH,'VOLU'
CMSEL,S,_Y
!*
VMESH,_Y1 !劃分網格
!*
CMDELE,_Y !以下三句為刪除自定義的組件
CMDELE,_Y1
CMDELE,_Y2
!*
C. ANSYS中網格劃分命令流，請幫忙解釋下這段命令流，謝謝了！
/PREP7 !前處理器
CSYS,0
WPAVE,0,0,0
CSYS,4 !將當前坐標系轉換為工作平面坐標系
VSEL,S, , ,1,2,1 !選擇體號為1~2的體
VSEL,A, , ,6,8,1 !補充選擇體號為6~8的體
!*******************補充說明
!VSEL,A, , ,6,8,2 !補充選擇體號為6，8的體，不選擇體號為7的體
VSEL,A, , ,11,13,1 !補充選擇體號為11~13的體
VSEL,A, , ,15,96,1 !補充選擇體號為15~96的體
VSEL,A, , ,99,109,1 !補充選擇體號為99~109的體
VSEL,A, , ,113,145,1 !補充選擇體號為113~145的體
VSEL,A, , ,148,149,1 !補充選擇體號為148~149的體
ASLV,S !通過當前的體選擇體下面的面
LSLA,S !通過當前的面選擇面下面的線
LESIZE,ALL,100E-6,,,,1 !將這些線的大小指定為100E-6為1份
VSWEEP,ALL !掃略劃分當前選擇的所有體(單元為六面體)
VSEL,S, , ,3,5,1 !選擇體號為3~5的體
VSEL,A, , ,9,10,1 !補充選擇體號為9~10的體
VSEL,A, , ,97,98,1 !補充選擇體號為97~98的體
VSEL,A, , ,150,155,1 !補充選擇體號為150~155的體
ASLV,S !通過當前的體選擇體下面的面
LSLA,S !通過當前的面選擇面下面的線
LESIZE,ALL,100E-6,,,,1 !將這些線的大小指定為100E-6為1份
VSWEEP,ALL !映射劃分當前選擇的所有體(單元為六面體)
VSEL,S, , ,110,111,1
VSEL,A, , ,146,147,1
VSEL,A, , ,156,157,1
ASLV,S
LSLA,S
LESIZE,ALL,100E-6,,,,1
MSHAPE,1,3D
MSHKEY,0
VMESH,ALL
VSEL,S, , ,112
VSEL,A, , ,158,161,1
ASLV,S
LSLA,S
LESIZE,ALL,500E-6,,,,1
!**********************************
MSHAPE,1,3D
MSHKEY,0
VMESH,ALL !以上三句話，採用FREE自由劃分方法進行劃分當前所有的體(單元四面體)
VSEL,S,MAT,,6,,,1 !選擇材料號為6的所有體
ASLV,S
LSLA,S
LESIZE,ALL,5E-3,,,,1
MSHAPE,1,3D
MSHKEY,0
VMESH,ALL
ALLSEL !全選
SAVE !保存
(1)對於實體，劃分網格一般有兩種形式：映射六面體網格(VSWEEP)和自由四面體網格(VMESH)。推薦採用前者，因為前者精度較高。但是，當結構模型比較復雜的時候，前者處理不了，可以採用後者。
(2)在讀ANSYS命令流的時候，先一段一段讀，搞清楚每一段做了一件什麼事情。在遇到特別關鍵的語句時，可以查閱ANSYS的HELP文件，裡面對每句話都有詳細的解釋，不足之處就是英文版的，讀起來有點費勁。
(3)幸運的是，市場上已經有這樣的書籍了，就是龔曙光的《ANSYS參數化編程與命令手冊》，在網上能找到電子版的。可參考以下鏈接下載：
http://www.bzfxw.com/soft/softdown.asp?softid=190162
D. 請 幫忙 解釋下 ANSYS 程序 命令流
esel,s,mat,,1 !選擇材料編號為1的單元
*get,enum1,elem,0,count ! 獲得單元數
*get,el,elem,0,num,min ! 獲得所選單元的最小編號
ksel,all ! 選擇所有keypoint
*get,nkp1,kp,0,num,max ! 獲得keypoint最大編號
ksel,none ! 不選擇keypoint
asel,none ! 不選擇面
vsel,none ! 不選擇體
/post1 ! 後處理
set,last ! 讀入最後一個載荷步結果
/prep7 ! 前處理
SHPP,OFF ! 關閉單元形狀警告
UPGEOM,1,LAST,LAST,'filname','rst',' ' !把最後載荷步的結果（位移）寫入幾何模型
！這里相當於給定一個初始干擾位移
*do,i,1,enum1 ! 循環（循環次數為單元數enum1）
*do,j,1,3 ! 內循環3次
nd=nelem(el,j) ！nd為最小編號單元的j節點編號
！若為四邊形單元（i，j，k，l）退化的三角形k,l重合.若為三角形（i，j，k）
！具體可看相應單元的介紹
knum1=nkp1+4*(i-1)+j !按上面的參數解釋做相應的計算
k,knum1,nx(nd),ny(nd),nz(nd) ! 建立keypoint knum1 坐標為節點nd的坐標
*enddo ！結束內循環
nd=nelem(el,j+2) ！nd等於單元el的j+2節點編號
k,knum1+1,nx(nd),ny(nd),nz(nd) ！建立keypoint
v,knum1-2,knum1-1,knum1,knum1+1 ！建體
el=elnext(el) ！elnext(el)意思是el的下一個單元
！比如我所選擇的單元為1 3 6 11 如果el=3 那麼elnext（el）=6
*enddo ！結束循環
numm,kp ！壓縮keypoint編號
cm,aal1,area ！建立面組建aal1
asel,r,ext ！重新選擇面
cm,aext,area ！建立組建aext
vdel,all ！刪除體
va,all ！通過選擇的所有面建立體
cmsel,s,aal1 ！選擇面組建aal1
cmsel,u,aext ！不選擇aext
adel,all,,,1 ！刪除所有面